View previous topic :: View next topic |
Author |
Message |
A.N.T.
Joined: 01 Jul 2006 Posts: 190
|
(Separately) Posted: Wed Aug 23, 2006 20:55 Post subject: Пометить файл/папку |
|
|
Часто необходимо каким-нибудь образом временно пометить файл или папку, например цветом... что бы потом его можно было легко найти среди кучи всего остального, что бы можно придумать? Просто хочется горячей клавишей пометить папку, позже при необходимости вернуть в прежнее состояние. Можно конечно воспользоваться скриптом, который меняет дату папки на текущую и поставить фильтр, но такой фильтр у меня уже есть |
|
Back to top |
|
|
CaptainFlint
Joined: 14 Dec 2004 Posts: 6151 Location: Москва
|
(Separately) Posted: Wed Aug 23, 2006 21:27 Post subject: |
|
|
1. Атрибутами.
2. Файловыми комментариями (Ctrl+Z). _________________ Почему же, ё-моё, ты нигде не пишешь "ё"? |
|
Back to top |
|
|
A.N.T.
Joined: 01 Jul 2006 Posts: 190
|
(Separately) Posted: Wed Aug 23, 2006 21:49 Post subject: |
|
|
1.Комментариями долго, не удобно(в данном случае)...
2.Что значит атрибутами? |
|
Back to top |
|
|
Nik
Joined: 01 Jan 2005 Posts: 583 Location: Киров
|
(Separately) Posted: Wed Aug 23, 2006 22:55 Post subject: |
|
|
Quote: | Можно конечно воспользоваться скриптом, который меняет дату папки на текущую и поставить фильтр, но такой фильтр у меня уже есть |
Как вариант - с помощью скрипта ставь дату, намного опережающую текущую (скажем, 2260 год ) и выделяй файлы с такой датой нужным цветом... _________________ Качественный хостинг. |
|
Back to top |
|
|
CaptainFlint
Joined: 14 Dec 2004 Posts: 6151 Location: Москва
|
(Separately) Posted: Wed Aug 23, 2006 23:02 Post subject: |
|
|
A.N.T. wrote: | 2.Что значит атрибутами? |
Зарезервировать для себя, скажем, что файлы/папки с атрибутом "только для чтения" будут для тебя этими самыми, помеченными, ну и задать для них шаблон поиска, плюс цвет навесить, чтобы сразу отличать. Разумеется, не обязательно привязываться к "только для чтения", можно некую комбинацию задать. Например, "только для чтения" + "системный" + неустановленный "архивный". Я нечто подобное уже применял для себя, но потом перешёл на систему с комментариями как более мощную. Менее удобно, конечно - в основном тем, что нельзя задавать комментарии сразу нескольким файлам, но в семёрке этот недостаток будет убран.
Nik wrote: | скажем, 2260 год |
Это будет затруднительно. (попробуй сам) _________________ Почему же, ё-моё, ты нигде не пишешь "ё"? |
|
Back to top |
|
|
A.N.T.
Joined: 01 Jul 2006 Posts: 190
|
(Separately) Posted: Thu Aug 24, 2006 08:14 Post subject: |
|
|
Всем спасибо! Больше конечно подходит вариант Nik'a, вот только менять дату на опережающую текущую ничем не грозит |
|
Back to top |
|
|
Batya
Joined: 15 Dec 2004 Posts: 2218 Location: Москва, Россия
|
(Separately) Posted: Thu Aug 24, 2006 17:16 Post subject: |
|
|
Значит так...
Используем Script Content Plugin.
Принцип работы - создаем файл-список, в котором сохраняем помечаемые файлы-папки. Настройте во всех скриптах один путь к файлу-списку.
В папке плагина создаем FilesInList.vbs:
Code: | Dim FSO, FilesList, oTextFile, AllText
FilesList = "D:\TotalCmd\PlugIns\Wdx\ScriptContent\FilesList.txt"
Set FSO = CreateObject("Scripting.FileSystemObject")
content = 0
Set oTextFile = FSO.OpenTextFile(FilesList, 1)
AllText = oTextFile.ReadAll
If InStr(1, AllText, filename, 1) > 0 Then
content = 1
End If
oTextFile.Close
Set oTextFile = Nothing
Set FSO = Nothing |
Настраиваем инишник плагина:
Code: | [Script]
Section=Files In List
[Files In List]
Script=FilesInList.vbs
LongName=1
ParseDirs=1
|
Для добавления в файл-список используем vbs-скрипт:
Code: | '==============================================================================
' Добавление полного имени файла в файл-список
'
' В качестве параметра указать:
' %L
'==============================================================================
Option Explicit
Dim FilesList
'============= Задайте файл-список ============================================
FilesList = "D:\TotalCmd\PlugIns\Wdx\ScriptContent\FilesList.txt"
'==============================================================================
If WScript.Arguments.Count = 0 Then
MsgBox "Не указан параметр - %L", _
vbOKOnly + vbExclamation, _
"Копирование имени файла в файл-список"
WScript.Quit
End If
Dim FSO, oTextFile, AllText, OTF, FileName
Set FSO = CreateObject("Scripting.FileSystemObject")
Set OTF = FSO.OpenTextFile(WScript.Arguments(0), 1)
If FSO.FileExists(FilesList) Then
Set oTextFile = FSO.OpenTextFile(FilesList, 1)
AllText = oTextFile.ReadAll
oTextFile.Close
Else
AllText = ""
End If
Do While Not OTF.AtEndOfStream
FileName = OTF.ReadLine
If InStr(1, AllText, FileName, 1) = 0 Then
Set oTextFile = FSO.OpenTextFile(FilesList, 8, 2)
oTextFile.WriteLine FileName
oTextFile.Close
End If
Loop
OTF.Close
Set oTextFile = Nothing
Set OTF = Nothing
Set FSO = Nothing
WScript.Quit |
Для удаления из файла-списка:
Code: | '==============================================================================
' Удаление полного имени файла из файла-списка
'
' В качестве параметра указать:
' %L
'==============================================================================
Option Explicit
Dim FilesList
'============= Задайте файл-список ============================================
FilesList = "D:\TotalCmd\PlugIns\Wdx\ScriptContent\FilesList.txt"
'==============================================================================
If WScript.Arguments.Count = 0 Then
MsgBox "Не указан параметр - %L", _
vbOKOnly + vbExclamation, _
"Удаление имени файла из файла-списка"
WScript.Quit
End If
Dim FSO, oTextFile, AllText, OTF, FileName
Set FSO = CreateObject("Scripting.FileSystemObject")
Set OTF = FSO.OpenTextFile(WScript.Arguments(0), 1)
Set oTextFile = FSO.OpenTextFile(FilesList, 1)
AllText = oTextFile.ReadAll
oTextFile.Close
Do While Not OTF.AtEndOfStream
FileName = OTF.ReadLine
If InStr(1, AllText, FileName, 1) > 0 Then
Set oTextFile = FSO.OpenTextFile(FilesList, 2)
AllText = Replace(AllText, FileName, "", 1, -1, 1)
AllText = Replace(AllText, vbNewLine & vbNewLine, vbNewLine, 1, -1, 1)
oTextFile.Write AllText
oTextFile.Close
End If
Loop
OTF.Close
Set oTextFile = Nothing
Set OTF = Nothing
Set FSO = Nothing
WScript.Quit |
При настройке цвета указываем Script Content Plugin, колонка Result = 1. |
|
Back to top |
|
|
A.N.T.
Joined: 01 Jul 2006 Posts: 190
|
(Separately) Posted: Thu Aug 24, 2006 17:45 Post subject: |
|
|
Сейчас попробую
Попробовал
2Batya
<Added> Спасибо конечно за идею.., но неудобно мне переключаться на колонки данном случае, если б удобно было я бы комментариями пользовался... Мне нужно просто тупо отметить цветом файл/папку позже вернуться к ней -> убрать цвет... + я не понял как должен цвет меняться, файлы в список FilesList.txt добавляются и...? |
|
Back to top |
|
|
Batya
Joined: 15 Dec 2004 Posts: 2218 Location: Москва, Россия
|
(Separately) Posted: Thu Aug 24, 2006 18:23 Post subject: |
|
|
Гм...
По-порядку.
1. Настроил плагин, как описано выше.
2. Заходишь в Настройки - Цвет - Определить цвета для типов файлов - Добавить - Шаблон - Закладка "Плагины", плагин "script", свойство "Result", операция "=", значение "1" - Сохранить - "Отмеченные файлы-папки" - ОК - Выбрать этот шаблон - ОК - Выбрать цвет - ОК - Перетащить новое правило в самый верх - ОК - ОК.
3. На кнопки вешаешь 2 скрипта - для добавления в список и для удаления из него.
4. Выделяешь файлы, жмешь кнопку "Добавить в список" - должны выделиться указанным тобой цветом. Если не выделяется, попробуй перезайти в папку.
Колонки вообще не нужны. Забудь про них. Главное - сделать шаблон, используя плагин. |
|
Back to top |
|
|
A.N.T.
Joined: 01 Jul 2006 Posts: 190
|
(Separately) Posted: Thu Aug 24, 2006 19:02 Post subject: |
|
|
Хых (как это я сразу не допёр, что нужно шаблон сделать)... Спасибо Batya, какой раз выручаешь... О таком решении я даже не догадывался... |
|
Back to top |
|
|
D1P
Joined: 20 Dec 2004 Posts: 2973 Location: Тбилиси
|
|
Back to top |
|
|
Nik
Joined: 01 Jan 2005 Posts: 583 Location: Киров
|
(Separately) Posted: Thu Aug 24, 2006 21:40 Post subject: |
|
|
Quote: | Это будет затруднительно. (попробуй сам) |
А в чём, собственно, проблема? _________________ Качественный хостинг. |
|
Back to top |
|
|
CaptainFlint
Joined: 14 Dec 2004 Posts: 6151 Location: Москва
|
(Separately) Posted: Thu Aug 24, 2006 21:44 Post subject: |
|
|
Nik wrote: | А в чём, собственно, проблема? |
Попробуй выставить 2260 год и посмотри, что получится. _________________ Почему же, ё-моё, ты нигде не пишешь "ё"? |
|
Back to top |
|
|
Nik
Joined: 01 Jan 2005 Posts: 583 Location: Киров
|
(Separately) Posted: Thu Aug 24, 2006 23:01 Post subject: |
|
|
Quote: | Попробуй выставить 2260 год и посмотри, что получится |
Ну ладно, я погорячился (D1P меня поймет ). Можно использовать 2016 _________________ Качественный хостинг. |
|
Back to top |
|
|
fa1con
Joined: 19 Aug 2006 Posts: 162
|
(Separately) Posted: Fri Aug 25, 2006 01:13 Post subject: |
|
|
2batja
Поражаюсь твоей находчивости. Где ты находишь столько времени в этом разбираться?
Не знаю как у вас, но у меня после проделанного довольно заметно увеличилось время открытия каталога. Я так понимаю плагин запускает скрипт FilesInList.vbs для каждого директории. Это довольно долго. Поэтому пользоваться я этим не буду. Хотя идея помечать каталоги мне очень понравилась.
Чтоб избавиться от тормозов предлагаю переписать скрипты "добавления"/"удаления" так что б он дописывал/удалял в/из комментария выделенных файлов какую-то строчку ("№;%:% например). Тогда можно будет настроить выделения цветом по "комментарий содержит". Так намного быстрее и плагина не надо. Одно плохо – комменты поганятся. |
|
Back to top |
|
|
|
|
You cannot post new topics in this forum You cannot reply to topics in this forum You cannot edit your posts in this forum You cannot delete your posts in this forum You cannot vote in polls in this forum
|
Powered by phpBB © 2001, 2005 phpBB Group
|