'======================================================================================
' Назначение: cоздание в активной панели файла с текстом из буфера обмена (при наличии)
' Условие:    пустой путь запуска
' Параметр:   <имя файла>
'======================================================================================
Set FSO = CreateObject("Scripting.FileSystemObject")
Dim WSH : Set WSH = CreateObject("WScript.Shell")
R = "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3\1407"
On Error Resume Next
A = WSH.RegRead(R) : If A > 0 Or Err.Number <> 0 Then WSH.RegWrite R, 0, "REG_DWORD"
Clip = CreateObject("htmlfile").ParentWindow.ClipboardData.GetData("text")
If A > 0 Then WSH.RegWrite R, A, "REG_DWORD"
On Error Goto 0
If IsNull(Clip) Or Trim(Clip) = "" Then WSCript.Quit
With New Regexp
  .Pattern = "[^ !-‚-›‘’–—\u0080-\u00FF\u0400-\u04FF\u20A0-\u20CF\u2100-\u214F\w]"
  .Global = True : If .Test(Clip) Then Enc = True Else Enc = False
End With : Name = WScript.Arguments(0) : Ext = FSO.GetExtensionName(Name)
F = WSH.CurrentDirectory & "\" & FSO.GetBaseName(Name) : FN = F & "." & Ext
While FSO.FileExists(FN) Or FSO.FolderExists(FN)
  i = i + 1 : FN = F & " (" & i & ")" & "." & Ext
Wend : FSO.CreateTextFile(FN,,Enc).Write Clip
WSH.Exec "%COMMANDER_EXE% /A /O /S /L=""" & FN & """"