'==================== VBS ====================
' Сравнение одноимённых каталогов в панелях ТС
' Условие:   Путь запуска — пустой
' Параметры: %Z%N %X"%P" "%T"
'=============================================
Set A = WSH.Arguments : If A.Count < 3 Then WSH.Quit
If A(1) = A(2) Then WSH.Quit
With CreateObject("Scripting.FileSystemObject")
  If StrComp(.GetAbsolutePathName("") & "\", A(1)) Then _
  AP = 2 : NP = 1 Else AP = 1 : NP = 2
  If Not .FolderExists("\\?\" & A(AP) & A(0)) Then WSH.Quit
  Check = Not .FolderExists("\\?\" & A(NP) & A(0))
End With
With CreateObject("WScript.Shell")
  If Check Then .Popup "В другой панели нет одноимённого каталога!",_
  1.7, " Сравнение/синхронизация одноимённых каталогов      ", 4144 : WSH.Quit
  .Run """%COMMANDER_EXE%"" /S=S:= """ & A(1) & A(0) & """ """ & A(2) & A(0) & """"
End With

'================================ VBS ================================
' Упаковать подкаталоги в одноимённые zip-архивы в выбранных каталогах
' Параметры: %WL "<имя подкаталога>"
'=====================================================================
Option Explicit : Dim A, Mask, FSO, ShA, List, Str, Arch
Set A = WSH.Arguments : If A.Count Then Mask = A(1) Else WSH.Quit
Set FSO = CreateObject("Scripting.FileSystemObject")
Set ShA = GetObject("new:{9BA05972-F6A8-11CF-A442-00A0C90A8F39}").Item.document.Application
Set List = FSO.OpenTextFile(A(0),,,-1)
Do: Str = List.ReadLine
  If Right(Str, 1) = "\" Then
  If FSO.FolderExists(Str & Mask) Then
    Arch = Str & Mask & ".zip"
    With FSO.CreateTextFile(Arch, 1) .Write "PK" & String(17, Chr(0)) :.Close: End With
    ShA.NameSpace(Arch).CopyHere Str & Mask, 13332
  End If
  End If
Loop Until List.AtEndOfStream : List.Close
Set List = Nothing : Set FSO = Nothing : Set ShA = Nothing

'=================== VBS ====================
' Поиск подкурсорного объекта в другой панели
' Параметры: %Z%N "%T" [/a]
' /a — ключ добавляет поиск в архивах.
'============================================
Set A = WSH.Arguments
If A.UnNamed.Count = 2 Then T = A(1) Else WSH.Quit
Set FSO = CreateObject("Scripting.FileSystemObject")
If Not FSO.FolderExists(T) Then WSH.Quit
Set WSS = CreateObject("WScript.Shell")
If A.Named.Exists("a") - ((Split(Split(FSO.OpenTextFile(WSS.Environment("Process")("COMMANDER_INI"))._
ReadAll, "LastSearchOptions=")(1), vbCr)(0) And 1024) = 0) = 0 Then Keys = "{TAB 6} "
WSS.Run "mshta ""javascript:close(clipboardData.setData('text','" & A(0) & "'))""", 7, 1
WSS.SendKeys "{TAB}" : PID = WSS.Exec("%COMMANDER_EXE% /O /S=F """ & T & """").ProcessID
Do : W = WSS.AppActivate(PID) : Loop Until W : WSS.SendKeys "^v" & Keys & "~%-"
Set WSS = Nothing : Set FSO = Nothing