CLARA-HU1-B-004-1280x720 и CLARA-HU1-B-004_video_640x368
Если использовался приведённый выше скрипт, то он не будет удалять папки из файла-списка. И слэши здесь не при чём. Ещё раз - удаляются вложенные папки для каждой папки из файла-списка. Т.е., если в файле списке содержится "H:\1\CLARA-HU1-B-004\Video", то тогда будут удалены все папки, вложенные в папку "H:\1\CLARA-HU1-B-004\Video", а сама папка останется.
'======================================================================
' Очищается каждая папка из файла-списка:
' файлы перемещаются в папку выше уровнем.
' При совпадении имён файлов выполняется автоматическое переименование.
' После выполнения переноса очищенные папки удаляются.
'
' Параметры:
' {файл-список}
'
' Пример параметров при вызове из TC:
' %L
'======================================================================
Option Explicit
Dim FSO, FF, F, oF
With WScript
If .Arguments.Count = 0 Then
MsgBox "Не заданы параметры!", vbOKOnly + vbCritical, "Очистка папок"
.Quit
End If
FF = .Arguments(0)
End With
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.OpenTextFile(FF, 1)
Do While Not .AtEndOfStream
F = Trim(.ReadLine)
If F <> "" Then
If FSO.FolderExists(F) Then
Set oF = FSO.GetFolder(F)
On Error Resume Next
MoveFromFolder oF, oF.ParentFolder
If Err.Number = 0 Then FSO.DeleteFolder oF.Path
Err.Clear
On Error GoTo 0
End If
End If
Loop
.Close
End With
Set FSO = Nothing
WScript.Quit
Sub MoveFromFolder(pSubFolder, pFolder)
Dim lF
For Each lF In pSubFolder.Files
MoveFile lF, pFolder
Next
For Each lF In pSubFolder.SubFolders
MoveFromFolder lF, pFolder
FSO.DeleteFolder lF.Path
Next
End Sub
Sub MoveFile(pFile, pFolder)
Dim lF
lF = pFolder
If Right(lF, 1) <> "\" Then lF = lF & "\"
lF = NextName(lF & pFile.Name)
FSO.MoveFile pFile.Path, lF
End Sub
Function NextName(pFilePath)
Dim lPath, lName, lExt, li, lAdd
Const lQ = 1 'Минимальное количество цифр в номере
With CreateObject("Scripting.FileSystemObject")
lPath = .GetParentFolderName(pFilePath)
If lPath <> "" Then lPath = lPath & "\"
lName = .GetBaseName(pFilePath)
lExt = .GetExtensionName(pFilePath)
NextName = pFilePath
Do While .FileExists(NextName)
li = li + 1
If li < 10^lQ Then
lAdd = Right(String(lQ, "0") & li, lQ)
Else
lAdd = li
End If
NextName = lPath & lName & "(" & lAdd & ")." & lExt
Loop
End With
End Function
Последний раз редактировалось Batya Ср июл 27, 2011 10:19, всего редактировалось 1 раз.
Спасибо Огромное Batya - отличный скрипт! (а то вручную удалять вложенные каталоги -с ума можно сойти особенно если их больше 500). И Спасибо Flasher - за помощь.
Теперь при имеющимся скрипте, этот вариант не удобен Поскольку речь идет о большом количестве многоуровневых вложенных каталогов, приходится каждый раз заходить в выбранный каталог и уже после этого удалять выделенные папки. До скрпта от Batya- приходилось так и делать. Жаль, что помочь с этим вопросом у него видимо времени нет. Но все равно, Большое Спасибо.
shveicar писал(а):Поскольку речь идет о большом количестве многоуровневых вложенных каталогов, приходится каждый раз заходить в выбранный каталог и уже после этого удалять выделенные папки.
Ничего не путаем? Мой скрипт сам удаляет очистившиеся папки. Никаких лишних телодвижений выполнять не требуется. Разница скриптов состоит только в том, что последний скрипт переименовывает файлы по глубине по счётчику, не затрагивая папки, а мой дублирует папки с совпавшими именами, которые находятся в активной панели. Кстати, в некоторых случаях удобней синхронизировать содержимое папок с одинаковыми названиями, чем бродить по всей глубине и производить пофайловое сравнение.
Ну да, все правильно, ему(скрипту) в данном случае не нравятся имена -
некоторых папок, впрочем главное задача выполнена, а каждому инструменту, свое применение.Спасибо.
список полных путей, при выделении одной папки например 5CLARA-CZ1-A-003-part5\ скрипт срабатывает и файл(с таким же именем что и папка) перемещается, но если выделить несколько папок
то он выдает ошибку, Понятно что ему не нравятся одинаковые имена папок и файлов(имена файлов вложенных в папки совпадают), а поскольку переименования по счетчику у него нет, вот он и капризничает. А теперь представте, В моей ситуации - лезть в каждую папку, и пытаться применить этот скрипт и проверять почему он срабатывает или нет, - сколько на это уйдет времени? Проще, конечно воспользоваться скриптом от Batya он сделает все что надо, останется только переименовать имена (если было совпадение) и отфильтровать дубликаты, -что также не сложно.[/code]
