Total Commander

Код: Выделить всё

' Поменять местами имена двух файлов
' Параметры: "<Путь к первому файлу>" "<Путь ко второму файлу>"
' Пример: "%%COMMANDER_PATH%%\Colors\Colors.ini" "%%COMMANDER_PATH%%\Colors\Colors_.ini"
'=====================================================
With CreateObject("WScript.Shell")
  F1 = .ExpandEnvironmentStrings(WScript.Arguments(0))
  F2 = .ExpandEnvironmentStrings(WScript.Arguments(1))
End With
With CreateObject("Scripting.FileSystemObject")
  .MoveFile F1, F1 & "x"
  .MoveFile F2, F1
  .MoveFile F1 & "x", F2
End With

Код: Выделить всё

'Описание:  Переключает цвета в TC, переименовывая друг в друга секции [Colors] и [Colors2]
'          Для вызова команд TC используется утилита TCMC (надо указать свой путь к ней)
'Параметр: Если есть (любой), то вместо обновления цветов в текущем сеансе, TC стартует снова
'--------------------------------------------------------------------------------------------
Option Explicit
Dim TCMC, TC, F, FSO, WSH, Str1 , Str2, Text  
'======== Укажите свой путь к TCMC.exe =======
TCMC = "%COMMANDER_PATH%\Utils\TCMC\TCMC.exe"
'=============================================
TC   = "%COMMANDER_PATH%\totalcmd.exe"
F    = "%COMMANDER_PATH%\wincmd.ini"
Set FSO = CreateObject("Scripting.FileSystemObject")
Set WSH = CreateObject("WScript.Shell")
Str1 = "[Colors]"
Str2 = "[Colors2]"
F    = GetPath(F)
TC   = GetPath(TC)
TCMC = GetPath(TCMC)
Text = FSO.OpenTextFile(F, 1).ReadAll
If InStr(1, Text, Str1, 1) > 0 Then Text = Replace(Text, Str1, "#" & Str1 , 1, -1, 1)
If InStr(1, Text, Str2, 1) > 0 Then Text = Replace(Text, Str2, Str1, 1, -1, 1)
If InStr(1, Text, "#" & Str1, 1) > 0 Then Text = Replace(Text, "#" & Str1, Str2, 1, -1, 1)
FSO.OpenTextFile(F, 2).Write Text
' Wscript.Sleep(200)
If WScript.Arguments.Count > 0 Then 
  WSH.Run """" & TCMC & """ CM24340", 1, True 'Выход
  WSH.Run """" & TC   & """"        , 1, True 'Запуск TC
Else
  WSH.Run TCMC & " CM494", 1, False           'cm_ColorConfig
  Wscript.Sleep(100)
  WSH.SendKeys "+{TAB 5}  {ENTER}{TAB 2}"
End If
Set WSH = Nothing
Set FSO = Nothing
WScript.Quit

Function GetPath(pPath)
  GetPath = FSO.GetAbsolutePathName(WSH.ExpandEnvironmentStrings(pPath))
End Function

Код: Выделить всё

' Поменять местами имена двух файлов и обновить цвета
' Параметры: "<Отн. путь к первому файлу>" "<Отн. путь ко второму файлу>"
' Пример: "Colors.ini" "Colors_.ini"
'=====================================================
With CreateObject("WScript.Shell")
  TC = .Environment("Process")("COMMANDER_PATH") & "\"
  F1 = TC & WScript.Arguments(0)
  F2 = TC & WScript.Arguments(1)
  With CreateObject("Scripting.FileSystemObject")
    If .FileExists(F1) And .FileExists(F2) Then
      .MoveFile F1, F1 & "'"
      .MoveFile F2, F1
      .MoveFile F1 & "'", F2
    End If
  End With
  .Exec(TC & "Utils\TCMC\TCMC.exe CM494")
  WScript.Sleep 60 ' Не работает - увеличиваем до 100
  .SendKeys "+{TAB 5}  ~"
End With

Код: Выделить всё

[em_SwapColors]
cmd=%COMMANDER_PATH%\ADDONS\kITUP\kITUP.exe
param=Light.up
menu=Сменить цвета
button=%COMMANDER_PATH%\ADDONS\kITUP\kITUP.exe,2

Код: Выделить всё

[Configuration]
DefaultDirectory=%COMMANDER_PATH%
;Заменяем цветовую схему Total Commander
[im|wincmd.ini|Colors]
BackColor=788488
;и так далее...
;Меняем действие кнопки на противоположное
[im|usercmd.ini|em_SwapColors]
param=Light.up
;Перезапуск Total Commander
[per|totalcmd.exe]

Код: Выделить всё

[Configuration]
DefaultDirectory=%COMMANDER_PATH%
;Заменяем цветовую схему Total Commander
[im|wincmd.ini|Colors]
BackColor=16579836
;и так далее...
;Меняем действие кнопки на противоположное
[im|usercmd.ini|em_SwapColors]
param=Dark.up
;Перезапуск Total Commander
[per|totalcmd.exe]