Total Commander

Код: Выделить всё

'========================================================
' Последовательное обратное переключение между дисками

' Параметры скрипта:
' [{Тип дисков}]
' Здесь {Тип дисков} может принимать значения:
' 1 - тома сменных накопителей;
' 2 - тома жёстких дисков;
' 3 - сетевые диски;
' 4 - оптические приводы;
' 5 - виртуальные диски.

' Авторcтво: Flasher, Batya
'========================================================
Option Explicit
'================ Изменяемые параметры ==================
Const DefaultDriveType = 1 'Тип дисков по умолчанию
'========================================================
Dim FSO, WSH, D, Drive, NewDrive, DriveType
Set FSO   = CreateObject("Scripting.FileSystemObject")
Set WSH   = CreateObject("WScript.Shell")
DriveType = DefaultDriveType
If WScript.Arguments.Count > 0 Then _
  DriveType = CInt(WScript.Arguments(0))
Drive    = UCase(FSO.GetDriveName(WSH.CurrentDirectory))
NewDrive = ""
For Each D In FSO.Drives
  If (UCase(D.Path) = Drive) Then
    If NewDrive <> "" Then _
      GoToDrive(NewDrive):Quit
  Else
    If CheckDrive Then _
      NewDrive = D.Path & ""
  End If
Next
'Если текущий диск первый, перейдём на последний диск
If NewDrive <> "" Then _
  GoToDrive(NewDrive):Quit

'Подходящих по условиям дисков нет. Выходим
Quit

Sub Quit
  Set D   = Nothing
  Set WSH = Nothing
  Set FSO = Nothing
  WScript.Quit 0
End Sub

Function CheckDrive
  CheckDrive = ((D <> "A:") And D.IsReady And (D.DriveType = DriveType) And (UCase(D.Path) <> Drive))
End Function

Sub GoToDrive(pDrive)
  Dim TCPath
  TCPath = WSH.ExpandEnvironmentStrings("%Commander_Path%")
  WSH.Run """" & TCPath & "\totalcmd.exe"" /S /O /L=" & pDrive, 1, True
End Sub

Код: Выделить всё

script.exe cm_xxx cm_yyy em_zzz ...