Total Commander

Код: Выделить всё

TOTALCMD#BAR#DATA
%ComSpec% /c for /f "delims=" %i in
('type %WL') do "%%COMMANDER_PATH%%\Utils\WinRAR\WinRAR.exe" x "%%i" -ibck -p- -inul "%P%%~ni" && del "%%i"
wcmicons.dll,31
Распаковать выбранные архивы c помощью WinRAR и удалить их при положительном результате

1

Код: Выделить всё

'====================================================== 
' Распаковать выбранные архивы в одноимённые папки 
' с удалением распакованных архивов 

' Параметры: %WL "<путь получателя>" 
' Пример:    %WL "%P"
'=================== Путь к WinRAR ====================
WinRAR = """%COMMANDER_PATH%\Utils\WinRAR\WinRAR.exe"""
'======================================================
With WScript.Arguments 
  If .Count = 0 Then WScript.Quit 
  List = .Item(0) : Path = .Item(1)
End With : If Right(Path, 1) <> "\" Then Path = Path & "\"
Set FSO = CreateObject("Scripting.FileSystemObject")
Dim WSH : Set WSH = CreateObject("WScript.Shell")
Set Dict = CreateObject("Scripting.Dictionary")
For Each Ext in Split("ZIP RAR RAR5 7Z 7ZIP ACE ARJ BZ2 CAB GZ ISO JAR LZH TAR UUE")
  Dict.Add Ext, ""
Next
For Each F in Split(FSO.GetFile(List).OpenAsTextStream(1,-1).ReadAll, vbNewLine) 
  If F <> "" And Dict.Exists(UCase(FSO.GetExtensionName(F))) Then
    BN = Path & FSO.GetBaseName(F)
    WSH.Run WinRAR & " x " & F & " -ibck -p- -inul """ & BN & "\""", 0, True
    If FSO.FolderExists(BN) Then
      If FSO.GetFolder(BN).Size = 0 Then FSO.DeleteFolder BN, 1 Else FSO.DeleteFile F, 1
    End If
  End If
Next : Set FSO = Nothing : Set WSH = Nothing : Set Dict = Nothing : WScript.Quit

Код: Выделить всё

If FSO.GetFolder(BN).Size = 0 Then 
       FSO.DeleteFolder BN, 1 : FSO.DeleteFile F, 1

Код: Выделить всё

'=========================================================
' Распаковка выбранных архивов в одноимённые папки
' с возможностью удаления правильно распакованных архивов

' Параметры: %WL "<путь получателя>" <флаг удаления: 1>
' Пример:    %WL "%P" 1
'====================== Путь к 7-zip =====================
Z7 = """%COMMANDER_PATH%\Utils\7-Zip\7z.exe"""
'=========================================================
With WScript.Arguments
  C = .Count : If .Count = 0 Then WScript.Quit
  List = .Item(0) : Path = .Item(1) : If C = 3 Then Del = .Item(2)
End With : If Right(Path, 1) <> "\" Then Path = Path & "\"
Dim WSH : Set WSH = CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
Const M = 0 : Set Dict = CreateObject("Scripting.Dictionary")
Exts = "zip 7z 7zip arj bz2 bzip2 cab chm chw cpio cramfs deb dmg doc" &_
" exe fat gz gzip hfs hxs iso lha lzma mbr msi ntfs ppt rar rpm scap " &_
"squashfs swm tar taz tbz tbz2 tgz vhd wim xar xls xz"
For Each Ext in Split(Exts) : Dict.Add Ext, "" : Next
For Each F in Split(FSO.GetFile(List).OpenAsTextStream(1,-1).ReadAll, vbNewLine)
  If F <> "" And Dict.Exists(LCase(FSO.GetExtensionName(F))) Then
    BN = Path & FSO.GetBaseName(F) : NN = BN : n = 0
    Do While FSO.FolderExists(NN)
      n = n + 1
      If n < 10^M Then PFix = Right(String(M, "0") & n, M) Else PFix = n
      NN = BN & " (" & PFix & ")"
    Loop : WSH.Run Z7 & " x """ & F & """ -o""" & NN & "\"" -y -p", 0, True
    If FSO.FolderExists(NN) Then
      If FSO.GetFolder(NN).Size Then
        If Del = 1 Then FSO.DeleteFile F, 1
      Else FSO.DeleteFolder NN, 1
      End If
    End If
  End If
Next : Set FSO = Nothing : Set WSH = Nothing : Set Dict = Nothing : WScript.Quit