Total Commander

Код: Выделить всё

'•••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••
' Cоздать указанное число копий/пустышек для каждого выбранного элемента
' с добавлением счётчика после базового имени, начиная с последнего номера

' Параметры: %WL "<путь назначения>" <число копий> <вставка до №> <расширение нового файла>
' Если указан 5-й параметр, то создаваться будут пустые элементы

' Примеры:   %WL "%P"   |   %WL "%T" 3   |   %WL "%P" 5 _v   |   %WL "%T" 1 "" txt

' Автор - Flasher ©
'•••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••••

Option Explicit : Dim C, List, Path, Count, Px, Ext, ShA, FSO,_
F, Test, Filt, Ex, BN, Max, i, N, M, Items, Cnt, Ln, x, Item, FN

With WScript.Arguments
  C = .Count : If C = 0 Then WScript.Quit
  If C = 1 Then MsgBox "Должно быть указано не менее 2-х параметров!", 48 : WScript.Quit 
  List = .Item(0) : Path = .Item(1) : If C > 2 Then Count = .Item(2) 
  If Count = "" Then Count = Trim(InputBox(String(4, vbLf) & "Введите число создаваемых копий"&_ 
  vbLf & "для каждого выбранного элемента:", Space(13) & "Создание копий выбранных элементов")) 
  If Not IsNumeric(Count) Then WScript.Quit : End If : If C > 3 Then Px = .Item(3)
  If C = 5 Then If .Item(4) <> "" Then Ext = "." & .Item(4) End If
End With : Set ShA = CreateObject("Shell.Application")
Set FSO  = CreateObject("Scripting.FileSystemObject")
Set List = FSO.OpenTextFile(List,,,-1)
Do : F = Trim(List.ReadLine)
  If FSO.FolderExists(F) Then
    Test = 1 : Filt = 160 : BN = FSO.GetFileName(F)
  Else
    Test = 0 : Filt = 192 : BN = FSO.GetBaseName(F)
    Ex = FSO.GetExtensionName(F) : If C < 5 And Len(Ex) Then Ext = "." & Ex
  End If : Max = 0
  For i = 1 To Len(BN)
    N = Right(BN, i) : If IsNumeric(N) Then M = N Else Exit For
  Next
  If M = N Then
    For i = 1 To Len(M)
      If Mid(M, i, 1) <> "0" Then Exit For
    Next : M = Mid(M, i)
  End if
  If M <> "" Then
    Max = CLng(M) : BN = Left(BN, Len(BN) - Len(M))
  ElseIf Right(BN, Len(Px)) <> Px Then
    n = 1
    For i = 1 To Len(Px)
      If Left(Px, i) = Right(BN, i) Then n = i
    Next : BN = BN & Mid(Px, n)
  End If : Set Items = ShA.NameSpace(Path).Items
  Items.Filter Filt, BN & "*" & Ext
  Cnt = Items.Count : Ln = Len(BN) + 1
  If Cnt Then
    For x = 0 to Cnt - 1
      Item = Items.Item(x) : M = Mid(Item, Ln, Len(Item) - Ln - Len(Ext) + 1)
      If IsNumeric(M) Then : If CLng(M) > Max Then Max = CLng(M) End If
    Next
  End If
  For i = 1 To Count
    FN = FSO.BuildPath(Path, BN & Max + i)
    If Test Then
      If C = 5 Then FSO.CreateFolder   FN & Ext  Else FSO.GetFolder(F).Copy FN, 0
    Else
      If C = 5 Then FSO.CreateTextFile(FN & Ext) Else FSO.CopyFile F, FN & Ext, 0
    End if
  Next
Loop Until List.AtEndOfStream