Total Commander

Сейчас у меня и у многих запуск Тотала происходит с загрузкой главного меню из файла Wcmd_Rus.mnu . Вопрос: Есть ли возможность запуска Тотала из уже открытого с другим файлом меню, к примеру, Wcmd_Rus_2.mnu?

Andrey_A
Прямой возможности нет. Можно держать или создавать дополнительный INI-файл, в котором будет прописан нужный ключ, и запускать Тотал с этим INI-файлом.

CaptainFlint а к примеру какой он должен быть ini файл и какой нужный ключ должен прописан?

Как обычно, секция 4.b файла TOTALCMD.chm:

[Configuration]
Mainmenu= Contains custom main menu location and file name

То есть, для запуска тотала с другим файлом главного меню нужно просто прописать этот файл меню в конфигурационный файл, а затем запустить тотал.

Недавно вновь вернулся к этому вопросу. Родился скрипт:

Код: Выделить всё

'================   Описание   ================= 
' Запуск Total Commander с теми же настройками, но с другим меню
'================  Параметры =================
'{Путь\сохранения\Wincmd_2.ini} {Путь\до\меню_2.mnu}
'================    Примеры    ================
' "%%COMMANDER_PATH%%\Wincmd_Two.ini" "%%COMMANDER_PATH%%\LANGUAGE\WCMD_RUS_Two.mnu"
'
' Автор:             Аверин Андрей (25.11.2010)
' Версия:          1.0
'==========================================
Dim FSO, WSH, TCS, WinCmd, WcmdMnu
Set TCS = CreateObject("TCSCRIPT.Helper")
Set FSO = CreateObject("Scripting.FileSystemObject") 
Set WSH = WScript.CreateObject("WScript.Shell")

WinCmd = FSO.GetAbsolutePathName(WSH.ExpandEnvironmentStrings(WScript.Arguments(0))) 
WcmdMnu = FSO.GetAbsolutePathName(WSH.ExpandEnvironmentStrings(WScript.Arguments(1))) 

TCS.SendCommand "cm_ConfigSaveDirHistory"                                   ' - сохранение настроек
FSO.CopyFile TCS.TCPath & "\Wincmd.ini", WinCmd, 1                      ' - дубликат Wincmd.ini
TCS.INIWrite WinCmd, "Configuration", "Mainmenu", WcmdMnu ' - запись в дубликат путь открываемого меню
WSH.run chr(34) & TCS.TCPath & "\TOTALCMD.exe" & chr(34) & " " & "/i=" & chr(34) & WinCmd & chr(34)

Set TCS = Nothing
Set WSH = Nothing
Set FSO = Nothing
WScript.Quit

Создайте любое меню в LANGUAGE\WCMD_RUS_Two.mnu

Total Commander

Запуск Тотала с нужным файлом главного меню

Запуск Тотала с нужным файлом главного меню