Копирование содержимого выделенных файлов в буфер обмена

[prog_san]

Здравствуйте.
Возникла задача: скопировать содержимое выделенных файлов в буфер обмена. Желательно перемежать полученный буфер строками с именами самих файлов. Хочется выделить файлы, нажать кнопку и вставить содержимое буфера обмена в Word документ.

Пример практического применения: формирование листинга исходных файлов проекта.

Поиск по форуму ничего конкретнее перенаправления в сlip не дал. Может быть кто-то уже решал подобные задачи?

[imig73]

prog_san
Создайте кнопки с командами:
cm_CopyNamesToClip - копировать имена в буфер и cm_CopyFullNamesToClip - копировать в буфер имена с путями.

[Flasher]

prog_san
Есть скрипты склеивания и кнопка.

imig73
Слово "содержимое" ни о чём не говорит?
И в новички prog_san записывать определённо уже довольно поздно.

[imig73]

Flasher
Да ладно вам, "содержимое" видел но не догнал. Мне тоже это надо
Со Старым новым годом!

[Flasher]

Мне тоже это надо

Что "это"? Текст группы файлов в буфер? Зачем вам?

С НГ по Цезарю!

[prog_san]

Есть скрипты склеивания и кнопка.

Спасибо!

[Flasher]

prog_san
Если очень надо одним скриптом, то на AutoHotKey (правда, без поддержки OEM и UTF-7/8 без ВОМ):

Код: Выделить всё

;:::::::::::::::::::::::: AHK ::::::::::::::::::::::::
; Отправить содержимое выбранных файлов в буфер обмена
; Параметры: %WL <разделитель>
; \n — перевод строки; \f — имя файла
; Примеры: %WL \n\f\n  |  %WL "\n\n===== \f =====\n\n"
;:::::::::::::::::::::::::::::::::::::::::::::::::::::
#NoEnv
#NoTrayIcon
ListLines, Off
SetBatchLines,-1
If !%0%
ExitApp
If 0 != 2
{ MsgBox, 4144, Текст файлов в буфер обмена, Укажите 2 параметра!, 1.5
  ExitApp
}

Delim = %2%
StringReplace Delim, Delim, \n, `r`n, All
Loop, Read, %1%
{ FileRead, Text, % A_LoopReadLine
  If Not ErrorLevel
    All .= StrReplace(Delim, "\f", RegExReplace(A_LoopReadLine, ".+\\")) . Text
}
If All !=
{ Clipboard =
  Clipboard = %All%
}

Либо на AutoIt (без поддержки OEM и UTF-7):

Код: Выделить всё

;:::::::::::::::::::::::: AU3 ::::::::::::::::::::::::
; Отправить содержимое выбранных файлов в буфер обмена
; Параметры: %WL <разделитель>
; \n — перевод строки; \f — имя файла
; Примеры: %WL \n\f\n  |  %WL "\n\n===== \f =====\n\n"
;:::::::::::::::::::::::::::::::::::::::::::::::::::::
If $CmdLine[0] = 0 Then Exit
If $CmdLine[0] <> 2 Then
  MsgBox(4144, " Текст файлов в буфер обмена", "Укажите 2 параметра!")
  Exit
EndIf
Global $All, $oList = FileOpen($CmdLine[1]), $Delim = StringReplace($CmdLine[2], '\n', @CRLF)
While 1
  $sLine = FileReadLine($oList)
  If @error Then ExitLoop
  $Text = FileRead($sLine)
  If Not @error Then $All &= StringReplace($Delim, '\f', StringRegExpReplace($sLine, '.+\\', '')) & $Text
WEnd
If $All <> "" Then ClipPut(StringRegExpReplace($All, '^\R+', ''))