Total Commander

Код: Выделить всё

[Script]
Section=Defaults|Extension|AddZeros|exe-arc up|js

Код: Выделить всё

'signatur.vbs by ricobautsch 

'Script for Script Content Plugin (c)Lev Freidin, 2005 
'http://www.totalcmd.net/plugring/script_wdx.html 
'http://wincmd.ru/plugring/script_wdx.html 
' 
'Этот скрипт показывает первые 10 байт файла в тектовом или hex представлении
'может быть полезен для поиска файлов с определенной сигнатурой
'This script returns the first 10 bytes in the file as text or hex-representation. 
'Could be usefull for example to search for files with a specified signatur 

const bHex = True 
const nCharCnt = 10 

Set fso = CreateObject("Scripting.FileSystemObject") 
Set oTextStream = fso.OpenTextFile(filename) 

If not oTextStream.AtEndOfStream Then 
  content_str = oTextStream.Read(nCharCnt) 
  
  If bHex Then 
    For i=1 To Len(content_str) 
      If content <> "" Then 
        content = content & " " 
      End If 
      
      hex_value = Hex(Asc(Mid(content_str,i,1))) 
      
      content = content & string(2 - len(hex_value), "0") 
      content = content & hex_value 
    Next 
  Else 
    content = content_str 
  End If 
End If 

oTextStream.Close 

Код: Выделить всё

'Script for Script content Plugin 
' van Dusen
' (c)Lev Freidin, 2005 
' http://www.totalcmd.net/plugring/script_wdx.html 
' http://wincmd.ru/plugring/script_wdx.html 

Dim fso, f1, f2 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set f1 = fso.GetFile(filename) 

sBaseIst = lcase(fso.GetBaseName(filename)) 
sExtIst = lcase(fso.GetExtensionName(filename)) 
sDateModF1 = f1.DateLastModified 
sExtSoll1 = "doc" 
sExtSoll2 = "pdf" 
Const ForReading = 1 


SELECT Case sExtIst 

   Case sExtSoll1 
      sResult = sExtSoll2 & " - сответствующий файл" 
      If fso.FileExists(sBaseIst & "." & sExtSoll2) Then 
         Set f2 = fso.GetFile(sBaseIst & "." & sExtSoll2) 
         sTimeDiff = DateDiff("n", sDateModF1, f2.DateLastModified) 
         If sTimeDiff < 0 Then 
            sResult = "2: " & sResult & " устарел"
         Else 
            sResult = "1: " & sResult & " свежий"
         End If 
         sResult = sResult & " (" & sTimeDiff & " Min. Diff.)" 
      Else 
         sResult = "3: " & sResult & " отсутствует" 
      End If 

   Case sExtSoll2      
      If fso.FileExists(sBaseIst & "." & sExtSoll1) Then 
         Set f2 = fso.GetFile(sBaseIst & "." & sExtSoll1) 
         sTimeDiff = DateDiff("n", sDateModF1, f2.DateLastModified) 
         If sTimeDiff > = 0 Then 
            sResult = "2: Файл устарел" 
         Else 
            sResult = "1: Свежий файл" 
         End If 
         sResult = sResult & " ("& sTimeDiff & " Min. Diff.)" 
      Else 
         sResult = "3: "& sExtSoll1 &" - соответствующий файл отсутствует" 
      End If 

   Case Else 
      sResult = "" 

End SELECT 

content = sResult 

Set fso=nothing 
Set f1=nothing 
Set f2=nothing

Код: Выделить всё

'relpath.vbs - Show relative path to file in the Branch view (Ctrl+B)
'Script for Script Content Plugin (c)Lev Freidin, 2005 
'http://www.totalcmd.net/plugring/script_wdx.html 
'http://wincmd.ru/plugring/script_wdx.html
Dim fso, f, tcs

Set fso = CreateObject("Scripting.FileSystemObject")
Set tcs = CreateObject("TCScript.Helper")

f = tcs.GetSrcPath
relpath = left(filename, len(filename) - len(fso.GetFileName(filename)))
relpath = Mid(relpath, Len(f)+1)
content = relpath

Set fso=nothing
Set tcs=nothing